home *** CD-ROM | disk | FTP | other *** search
/ Shareware Games Galore! / Shareware Games Galore!.iso / arcade / gameser5 / chase.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1980-01-01  |  2.1 KB  |  110 lines
  1. 1  CLS:KEY OFF
  2. 10  PRINT "THIS IS THE GAME OF CHASE"
  3. 20  PRINT "WANT INSTRUCTIONS";
  4. 30  INPUT C$
  5. 40  IF LEFT$(C$,1)="N" THEN 140
  6. 50  IF LEFT$(C$,1)<>"Y" THEN 20
  7. 60  PRINT "YOU ARE '*' IN A HIGH VOLTAGE MAZE WITH 5"
  8. 70  PRINT "SECURITY MACHINES '+' TRYING TO DESTROY YOU"
  9. 80  PRINT "YOU MUST MANEUVER THE SECURITY MACHINES INTO"
  10. 90  PRINT "THE MAZE 'X' TO SURVIVE.  GOOD LUCK !!!"
  11. 100  PRINT "MOVES ARE 7,8,9"
  12. 110  PRINT "          4,5,6"
  13. 120  PRINT "          1,2,3   0 TO END THE GAME"
  14. 130  PRINT
  15. 140  DIM A(10,20),E(21),F(21)
  16. 150  LET G=0
  17. 160  FOR B=1 TO 10
  18. 170  FOR C=1 TO 20
  19. 180  LET A(B,C)=0
  20. 190  IF B=1 THEN 240
  21. 200  IF B=10 THEN 240
  22. 210  IF C=1 THEN 240
  23. 220  IF C=20 THEN 240
  24. 230  GOTO 250
  25. 240  LET A(B,C)=1
  26. 250  NEXT C
  27. 260  NEXT B
  28. 270  FOR D=1 TO 21
  29. 280  LET B=INT(RND(1)*8)+2
  30. 290  LET C=INT(RND(1)*18)+2
  31. 300  IF A(B,C)<>0 THEN 280
  32. 310  LET A(B,C)=1
  33. 320  IF D<6 THEN 340
  34. 330  GOTO 350
  35. 340  LET A(B,C)=2
  36. 350  IF D=6 THEN 370
  37. 360  GOTO 380
  38. 370  LET A(B,C)=3
  39. 380  LET E(D)=B
  40. 390  LET F(D)=C
  41. 400  NEXT D
  42. 410  FOR B=1 TO 10
  43. 420  FOR C=1 TO 20
  44. 430  IF A(B,C)<>0 THEN 460
  45. 440  PRINT " ";
  46. 450  GOTO 540
  47. 460  IF A(B,C)<>1 THEN 490
  48. 470  PRINT "X";
  49. 480  GOTO 540
  50. 490  IF A(B,C)<>2 THEN 520
  51. 500  PRINT "+";
  52. 510  GOTO 540
  53. 520  IF A(B,C)<>3 THEN 540
  54. 530  PRINT "*";
  55. 540  NEXT C
  56. 550  PRINT
  57. 560  NEXT B
  58. 570  LET B=E(6)
  59. 580  LET C=F(6)
  60. 590  LET A(B,C)=0
  61. 600  INPUT Y
  62. 610  ON Y+1 GOTO 950,640,640,640,650,690,650,620,620,620
  63. 620  LET B=B-1
  64. 630  GOTO 650
  65. 640  LET B=B+1
  66. 650  ON Y GOTO 660,690,680,660,690,680,660,690,680
  67. 660  LET C=C-1
  68. 670  GOTO 690
  69. 680  LET C=C+1
  70. 690  IF A(B,C)=1 THEN 970
  71. 700  IF A(B,C)=2 THEN 990
  72. 710  LET A(B,C)=3
  73. 720  LET E(6)=B
  74. 730  LET F(6)=C
  75. 740  FOR D=1 TO 5
  76. 750  IF A(E(D),F(D))<>2 THEN 930
  77. 760  LET A(E(D),F(D))=0
  78. 770  IF E(D)>=B THEN 800
  79. 780  LET E(D)=E(D)+1
  80. 790  GOTO 820
  81. 800  IF E(D)=B THEN 820
  82. 810  LET E(D)=E(D)-1
  83. 820  IF F(D)>=C THEN 850
  84. 830  LET F(D)=F(D)+1
  85. 840  GOTO 870
  86. 850  IF F(D)=C THEN 870
  87. 860  LET F(D)=F(D)-1
  88. 870  IF A(E(D),F(D))=3 THEN 990
  89. 880  IF A(E(D),F(D))=0 THEN 910
  90. 890  LET G=G+1
  91. 900  GOTO 920
  92. 910  LET A(E(D),F(D))=2
  93. 920  IF G=5 THEN 1010
  94. 930  NEXT D
  95. 940  GOTO 410
  96. 950  PRINT "SORRY TO SEE YOU QUIT"
  97. 960  GOTO 1020
  98. 970  PRINT "ZAP!!! YOU TOUCHED THE FENCE !!!!!"
  99. 980  GOTO 1020
  100. 990  PRINT "** YOU HAVE BEEN DESTROYED BY A LUCKY COMPUTER **"
  101. 1000  GOTO 1020
  102. 1010  PRINT "YOU ARE LUCKY **YOU DESTROYED ALL THE ENEMY**"
  103. 1020  PRINT "WANT TO PLAY AGAIN";
  104. 1030  INPUT C$
  105. 1040  IF LEFT$(C$,1)="Y" THEN 150
  106. 1050  IF LEFT$(C$,1)<>"N" THEN 1020
  107. 1060  PRINT "HOPE YOU DON'T FEEL FENCED IN."
  108. 1070  PRINT "TRY AGAIN SOMETIME"
  109. 1080  END
  110.